%
% Файл Алексея Малистова с добавлениями С.В.Костина.
%

% mode:=localfont; mag:=4;
% fontmaking:=1;
mode_setup;
font_size=10pt#;
em#:=10pt#; cap#:=7pt#;
thin#:=1/3pt#; thick#:=5/6pt#;
o#:=1/5pt#;
define_pixels(em,cap);
define_blacker_pixels(thin,thick);
define_corrected_pixels(o);
errorstopmode;

% Символ 1. Левая угловая скобка (\lmy).

beginchar("1",.6em#+3o#,cap#,0);
z0 = (4o,0.36h);
x1 = w-5o;
x2 = w-5o;
z1 - z0 = whatever * dir 45;
z2 - z0 = whatever * dir -45;

pickup pencircle scaled thin;
draw z1--z0--z2;
endchar;

% Символ 2. Правая угловая скобка (\rmy).

beginchar("2",.6em#+3o#,cap#,0);
z0 = (w-4o,0.36h);
x1 = 5o;
x2 = 5o;
z1 - z0 = whatever * dir 135;
z2 - z0 = whatever * dir -135;

pickup pencircle scaled thin;
draw z1--z0--z2;
endchar;

% Символ 3. Параллелограмм (\parallelogram).

beginchar("3",0.9em#+2o#,cap#,0);
z0 = (2o,o);
z2 = (w-2o, 0.9h);
z3 - z0 = z2 - z1 =  whatever * dir 70;
z1 - z0 = z2 - z3 =  whatever * dir 0;

pickup pencircle scaled thin;
draw z0--z1--z2--z3--cycle;
endchar;

% Символ 4. Треугольная пирамида (\tetrahedron).

beginchar("4",.9em#+2o#,cap#,0);
z1 = (2o,o);
z2 = (w-2o,o);
z1 - z2 = (z3 - z2) rotated 60;
z2x = 2/3[z1,z2];
z2y - z2x = whatever * ( z3 - z1);
z2y = whatever[z2,z3];

pickup pencircle scaled thin;
draw z2x--z3--z1--z2x--z2y--z3;
endchar;
               
% Символ 5. Параллелепипед (\parallelepiped).

beginchar("5",0.9em#+2o#,cap#,0);
z0 = (2o,o);

vardef zd@# = (z@# - z0) enddef; 

z0 + zd1 + zd2 + zd3 = (w-2o, h);
zd1 = whatever * right;
zd2 = whatever * up;
zd3 = .5 zd1 rotated 40;

pickup pencircle scaled thin;
draw z1--(z1+zd2)--z2--z0--z1--(z3+zd1)--(z1+zd2+zd3)--(z2+zd3);
draw z1--(z1+zd3);
draw z2--(z2+zd3);
draw (z1+zd2)--(z1+zd2+zd3);
endchar;

% Символ 6. Логическое отрицание (\negmy).

beginchar("6",.6em#+3o#,cap#,0);
z0 = (w-6o,1.0h);
z1 = (6o,1.0h);
z2 = (w-6o,0.0h);

pickup pencircle scaled 4.0;
draw z1--z0--z2;
endchar;

% Символ 7. Треугольная пирамида (старый вариант).
%
% beginchar("6",.8em#+2o#,cap#,0);
% z0 = (2o,0);
% z1 = (w-2o)*right;
% z2 = whatever * z1 rotated -30;
% z3 = whatever * z1 rotated 60;
% y3 = h;
% x2 = x3;
%
% pickup pencircle scaled thin;
% draw z0--z2--z1--z0--z3--z1--z2--z3;
%
% endchar;

end.